Top / 練習用ページ / マクロ

マクロ Edit

こんなマクロが便利、こんなの使ってるよ。そんなマクロ達の情報。
ここに掲載されているものは一例なので、あくまで参考として、自分にあった物に組み替えて利用しよう。

マクロとは? Edit

  • 一連の動作をボタン1つで実行できるようする機能。
    • マクロ1個で、最大6個のコマンドを設定可能。
    • マクロは、1ページ毎に10個、全10ページで1セット。
    • マクロセットは、外部ファイルに保存・読み込み可能。
      /savemacro 任意のマクロ名
      /loadmacro 任意のマクロ名
    • マクロは、1行毎に処理時間を必要とする。
      マクロ6行を実行する時間 = おおよそ pause1    相当
      マクロ1行を実行する時間 = おおよそ pause0.17 相当

/pauseコマンドについて Edit

  • /pause n は、指定した時間を置くコマンド。(n は、1〜599までの整数)
    /pause 1 = ディレイ6 = 0.096秒
  • ディレイとは、技・魔法・アイテムを、次回使用するまでに必要な待機時間。
    • テクニックやアイテム毎に、それぞれディレイ値が設定されている。
      • 例)ディレイ値 300 のテクニックならば、pause50 に相当 = 4.8秒
    • ただし、実際のディレイには、色々な補正が掛かるので注意。
      • スキル値、ST残量、装備品による補正、武器の[攻撃間隔]値、Buff効果など
  • pause中は、他のマクロの実行が出来なくなる。
    • ただし、テクニック欄やアイテム欄から、直に使用する事は可能。
    • 無駄に大きいpause値を使うと、その分だけ不利になる。
      逆に、小さ過ぎるpause値を使うと、意図した動作が行われない可能性がある。
  • pauseの意味
    • 技や魔法が発動するのに要する時間やディレイを考慮したマクロを組む時に使う。
    • マクロの文法は正しくても、意図した動作をしない場合がある。
      そのような時に/pauseで時間を置いてやると解決することがある。

発動時間とディレイ Edit

  • 発動時間
    • あるテクニックを使用してから、別のテクニックを使用できるようになるまでの時間。
      値が大きいほど、隙が大きい。
  • ディレイ
    • あるテクニックを使用してから、そのテクニックを再度使用できるようになるまでの時間。
      値が大きいほど、間隔が長くなる。
       
  • 魔法の場合、技とは以下の点で異なる。
    • 発動時間=詠唱時間で、詠唱完了と同時に次の行動を開始できる。
    • ディレイは、多くの魔法で共通。全部で3系統ある。
       
  • アイテムの場合
    • ディレイ状況と、マクロのアイコンを同期させる事はできない。
    • ディレイ付きのアイテムと、ディレイ無しのアイテムがある。
      • ディレイ付き*1 : ポーション類、包帯、やきいも(例外的な食品)、等
      • ディレイ無し  : 飲食物、アニマルケイジからペットを取り出す、等
         
  • 発動時間やディレイの計測は、測定用マクロを参照。

アイテムの操作について Edit

  • Itemウィンドウ内を、「インベントリ」と記載。
    • インベントリには、番号が割り当てられている。 → [公式サイト>マクロ登録について]
  • 各種アイテム操作関連のコマンドには、「正式名称」か「インベントリ番号」を指定する必要がある。
    /useitem [グレート スタミナ ポーション]   ← GSPを使用
    /useitem 8                                ← インベントリ8番のアイテムを使用
    2つ目の例は、インベントリ8番に置いてあるアイテムが、
      ・GSPならば、1つ目の例と同じ結果になる。
      ・バナナミルクなら、バナナミルクを飲む。
      ・装備品なら、使用できないからコマンドが無効になる。
     
  • インベントリに同名アイテムが複数ある場合、インベントリ番号のより若い番号の物が対象となる。(1番から順に判定していく為)
    • 例えば、装備変更マクロで、主武器と予備武器が同名だと、期待通りの動作をしない場合もある。
  • 正式名称の代わりに、ワイルドカードを用いた表記が可能。
     
  • アイテムを、マウスカーソルにドラッグした状態を「アイテムを掴む」と記載。
    • 掴んだアイテムは、ItemウィンドウのUSEボタンにドロップすると、使用できる。 (ただし、数量1個の場合のみ使用可能)
    • 掴んだアイテムが装備品なら、自分のキャラクターにドロップすると装備変更ができる。
  • 掴んだアイテムは、インベントリとは別の場所として扱われる。
    • 専用の操作コマンド( /swapitembox と /swapequip )が用意されている。

ワイルドカードについて Edit

  • アイテム名の指定には 「*」 (ワイルドカード) が使用できる。
    • 同名と判定できるものが複数ある場合、インベントリ番号のより若い番号の物が対象になる。(1番から順に判定していく為)
  • アイテムの正式名称は、装備品の材質や製作者名まで厳密に判定される。
    /equipitem [*タワー シールド*]
    とすれば、グレード・材質を問わずタワー シールドを装備できる。
    NG/HGの「シルバー タワー シールド」でも、MGの「ブロンズ タワー シールド <製作者名>」でも、タワー シールドと付くならOK。
    /equipitem [*シールド]
    とすれば、「ドラゴン シールド」「ブロンズ タワー シールド」「スチール ウォー シールド」「ガーズマン シールド」 等を装備できる。
    ただし、後ろのワイルドカードが無いので、<製作者名> の入るMG品や、「シールド オブ セイレーン」等は装備できない。
    当然、シールドが含まれていない「コダチ」や「バックラー」は装備できない。
 
  • 余談だが、「ノアピース [ ディバイン シールド ]」を拾った場合、
    /equipitem [*シールド*]
    となっていると、より若いインベントリ番号に「他の装備できるシールド」が無いと、ノアピースを装備しようと試みて装備変更に失敗し、/equipitemコマンドが終了する。
    • そのため、次の行の盾技が発動しない、という事態に陥ることがある。
    • /equipitemコマンドでは、掴んでいるアイテムは対象にならないので、ノアピースを掴んでおけば、盾の装備変更の動作に支障はなくなる。

装備変更について Edit

  • 技の使用には、多くの場合、装備条件が設定されている。
    • 例) 刀剣チャージドスラッシュを使うには、刀剣系の武器を装備していなければならない。
  • 技を使用するマクロに、装備変更コマンドを組み込むことで、格段に戦い易くなる。
    • 盾と両手武器を同時に扱う。
    • 刀剣+弓、素手+棍棒など、2系統の武器の技を自在に扱る。(通称「2武器」)
 
  • 装備変更マクロは、今後「装備変更ディレイ」(仮称)が導入されると、機能しなくなる可能性がある。

装備変更とテクニック実行の関係 Edit

  • マクロを組む上で、テクニック実行と装備変更は切っても切り離せない関係にある。
    幾つか引っかかりやすいポイントがあるので、例と共に参照されたし。
  • 一般に、テクニック実行は実行を試みる時の装備が参照される。これは基本的なこと。
    では、次の例はどうだろうか。
    /equipitem [*チョッパー*]
    /cmd [チャージド スラッシュ]
    /equipitem [*シールド*]
    /cmd [先行入力防止]
    チャージドスラッシュを実行してすぐに盾に持ち替えるマクロ。
    一見するとちゃんと動いてくれそうに思える。ところが、これは期待通りに動作してくれない。
    実は /cmdコマンドでのテクニック実行は、マクロ一行分の時間を経た後 なのだ。
    1フレーム遅れる、実行予約に1フレームかかる、と置き換えてもよい。
    つまり上記のマクロでは、チャージドスラッシュを実行しようとする段階では、既に盾に装備変更されているため、チャージドスラッシュの装備条件を満たさない、ということになる。
    これを解決するためには、例えば以下のように組めばよい。
    /equipitem [*チョッパー*]
    /cmd [チャージド スラッシュ]
    /cmd [先行入力防止]            ← この行で実行が試みられる
    /equipitem [*シールド*]
    或いは
    /cmd [チャージド スラッシュ]
    /equipitem [*チョッパー*]      ← この行で実行が試みられる
    /equipitem [*シールド*]
  • 更に、次のような例を見てみよう。
    /equipitem [*スペル ブック]
    /cmd [ヒーリング]<1>
    /cmd [先行入力防止]            ← この後にもう一行分だけ時間が必要
    /equipitem [*ナイフ*]
    魔法を唱える時だけチャージ武器に持ち替えるマクロ。これも一見するとちゃんと動作しそうである。
    しかし、やはりこれも期待通りにはならない。魔法チャージは成功するのだが、チャージ開放がエフェクトのみで実際には発動しない状態となるのだ。
    これは先行入力防止テクニックの後に、もう一行空白なりをいれることで解決する。
    魔法チャージを開放するためには、マクロ二行分の間、チャージ武器を外してはならない。

    ※魔法チャージのモーションキャンセル
  • 余談だが、魔法チャージのもう一つの特徴として開放モーションはモーションキャンセルできるというものがある。
    /equipitem [*スペル ブック*]
    /cmd [ヒーリング]<1>
    /cmd [リバイタル]<1>
    /cmd [先行入力防止]
    このようなマクロを実行した場合、まず一度目はヒーリングが魔法チャージされ、二度目に開放される。
    チャージ開放にマクロ二行分の間が必要であれば、「鍛冶」の先行入力によってリバイタルは詠唱されない筈である。
    しかし実際には、ヒーリングを開放して、即、リバイタルの詠唱に入る(モーションキャンセルの動作)。
    このように/cmdを並べると、(例えそれを望まずとも)開放にかかる時間を無視した動作となる(なってしまう)。
    …この仕様には魔法チャージマクロとターゲット指定マクロで苦しめられる。

盾マクロ(基本) Edit

  • 両手武器と盾を同時に扱うためのマクロの組み方を、一般に「盾マクロ」と呼ぶ。
    これを使えば、両手武器を装備しているときでも、瞬時に盾を装備してガード可能。
  • 基本的には、次の2つの事を行う。
    盾技を使用するマクロに、盾を装備するマクロを組み込む。
    /equipitem [盾]
    /cmd [シールド ガード]    ← 盾技全般
    武器攻撃のマクロに、武器を装備するマクロを組み込む。
    /equipitem [両手武器]
    /cmd [アタック]           ← アタックではなく、武器に対応した技でも良い
    これらを、盾技と、アタックや全ての武器テクニックに適用しておく。

  • 1つのマクロに、2回装備変更を組み込む場合
    /equipitem [盾]
    /cmd [シールド ガード]    ← 盾技全般
    /pause 10                 ← 適宜調整する
    /equipitem [両手武器]
    とすれば、盾技が終わった後に自動的に、両手武器に変更することができる。
  • ただし、/pauseを入れると、大きな隙ができたり、ガードロストの危険がある。
    • コマンドの実行時間を見越した /pause 1 以外は入れないほうが無難。
  • テクニック使用後に装備変更させるなら、「武器攻撃の後に盾を持つ」方がリスクがの少ない。
    /equipitem [両手武器]
    /cmd [アタック]           ← アタックではなく、武器に対応した技でも良い
    /pause 1
    /equipitem [盾]
    アタックの発動時点で、威力値と命中値の決定・武器の消耗処理・ディレイ発生は済んでいるので、攻撃モーション中に盾に持ち替えても問題ない。

装備品を必ず外すマクロ Edit

  • トグル(状態のON/OFFを切り替える)指定をすれば、装備を外すことができる。
    /equipitem [クロース キャップ] tgl
    これだと、装備していれば外し、装備していなければ装備する、という動作になるので、
    /equipitem [クロース キャップ]
    /equipitem [クロース キャップ] tgl
    1行目 : クロースキャップを装備する。装備している場合はそのまま。
    2行目 : クロースキャップを装備していたら外す。
    装備中かどうかに関係なく、1行目で常に装備された状態になる。よって、2行目で必ず装備が外れる。

左右どちらにも装備できる武器を、必ず左手に装備するマクロ Edit

  • /equipitemコマンドだと、装備部位の指定はできない。そこで次のようにマクロを組む。
    /swapitembox [左手に装備したい武器]
    /swapequip 左手
    /swapitembox *
    1行目 : 対象アイテムを掴む。
    2行目 : 「掴んだアイテム」と「左手で装備中のアイテム」を入れ替える。
    3行目 : 入れ替えで掴んだアイテムを、インベントリの一番若い空きスロットに戻す。
    左手が装備無しだったら、2行目の結果は「武器を左手に装備する+何も掴んでない状態」となる。

コマンドの先行入力について Edit

先行入力とは? Edit

  • 読んで字の如し、テクニック実行を先行して入力できる、というもの。
  • コマンドを実行できない状態(主に、他のテクニックを実行中)で、新たなコマンドが入力されると、
    実行を予約(保留)しておいて、実行可能になった段階で即座に実行しようとする機能である。
  • 重要なのは以下の点。
    • 予約テクニックは一つだけで、常に最新のもので上書きされる。
    • 予約テクニックが実行できない(覚えていない・装備が違う・対象が違う・etc…)場合も予約される。
      • 当然、実行はされない(できない)。
      • NPC専用テクニックでも予約されるが、実行されない。
    • 存在しないテクニックは受け付けず、コマンド自体が無効となる。
  • つまり、このページを含むマクロの説明でよく出てくる、「存在はするが覚えていない」「先行入力防止」テクニックとは、
    使用することができないテクニックを最後に(常に)予約することで、結果的に機能させなくする という挙動で成り立っている。

先行入力防止について Edit

  • 仕組みは、前述の通り。
    /equipitem [*メイス*]
    /cmd [チャージド ブラント]
    /cmd [ニート クラッシャー]
    /cmd [ウェポン ディザーム]
    /cmd [複製]                   ← 存在するが、自分が覚えていないテクニック
    採集や生産系のテクニックは、そのほとんどに装備や対象の条件があるため、この目的で用いるのには適している。
  • wikiのマクロ解説では、次のように記述する。
    /cmd [先行入力防止]

代入文字について Edit

  • 代入文字一覧 → [公式サイト>代入文字一覧]

%t や ターゲット指名 Edit

  • %t という代入文字は、現在、PCが指定してするターゲット名に置換される。
    (何もターゲットしていない場合は TARGET という文字に置換される)
    しかしこれは、あくまで「ターゲット名」であって、「ターゲットそのもの」ではない
  • どういうことかは、次のようなマクロを組めばすぐに分かる。
    /cmd [アタック] %t
    このマクロを用いて、例えばミーリム城門前の「ベビー スネーク」あたりをターゲットして実行してみよう。
    (極稀なケースを除き)タゲった相手が目の前にいても、<ターゲットが範囲外です>と出て上手くいかない筈である。
    つまりあくまで文字だけなので、どのベビー スネークか判断できないのだ。
    /cmd [アタック] ベビー スネーク
    でも挙動は同じ。
  • %t が、実際のターゲットそのものと一致する保証があるのは、PCの名前くらいである。
  • これは他の代入文字でも変わらない。よく注意しよう。

<enemy> <player> <pet> / <1> <pet1> Edit

  • コマンド中でのターゲット指定に使われる<near enemy>、<player>、<near pet>等といった文字。
    これらは、言わば助詞である。決して、代名詞ではない
    これら単体では何も意味を持たない。その後に続く名前がどういう種類のものかを指定しているだけだ。
    • だから、「近くの敵をターゲットしたい」といった場合に次のようなコマンドは使えない。
      /target <near enemy>   ← 名前が指定されていないので、コマンドとして機能しない
      これはよくハマりやすいので、よく注意すること。
  • これに対して、代名詞となる文字群がある。<1>〜<5>や<lt>、<pet1>〜<petN>等がそうだ。
    これらは代入文字のように単に置換されるのではなく、ターゲットそのものを指定することになる。
    • 例えば、
      /target <pet1>
      /cmd [チェリッシング]
      /target <lt>
      このようにして使うことが可能。

/locktargetコマンドの動作について Edit

  • ロックターゲットモードとは、ターゲットを中心に視点を変える機能。
    • つまり、ターゲットの動きに合わせて、視点(キャラクターの方向)を自動的に追尾させる。
    • ロックターゲット可能な距離は、装備している武器のレンジに依存。
      (例えば、素手では短く、弓を持つと遠くでも捕捉できる)
  • 050629パッチで、on/off の明示が利くようになった。
    /locktarget         ← ON・OFFを切り替える
    /locktarget on      ← 常に ON  にする
    /locktarget off     ← 常に OFF にする

/locktarget on(off)のススメ Edit

  • /locktargetだと、そのマクロを連打した場合、 ロックターゲット on/off どちらの状態にもなり得るので、期待通りの動作をするとは限らない。
    そこで、/locktargetコマンドに on(off) を追記することで、比較的安定した動作になる。
  • ロックターゲット ONだと、常に相手の方を向けるので、
    /locktarget on
    /pause 3                ← 相手の方を向き終わるまでの時間
    /cmd [ヒーリング]
    とすれば、マクロボタンを押した時点で相手が真後ろに居ても、回復魔法ヒーリングを使う頃には相手を自分の正面に捉えるているので、確実にテクニックを使用できる。
 
  • 移動や行動すると効果が切れるテクニックには、
    /locktarget off         ← ロックターゲットによる移動(方向転換)を防ぐ
    /automove off           ← 移動を防ぐ
    /autobattle off         ← アタック使用を防ぐ
    /cmd [スワン ダンス]
    を組み込むのがオススメ。
  • 自分自身をターゲットすると、/locktargetと/autobattleが自動的に解除されるので
    /target %1                  ← 自分自身をターゲットする
    /cmd [メディテーション]
    /target %lst                ← 前回のターゲットを、再ターゲットする
    というやり方もある。

/locktargetの不安定な動作 Edit

  • 手動カメラモード(M1、M2)では、妙な動作をする。 → コマンド
    • マクロで/locktargetを使う場合は、/locktarget より後に /autolock on(ないしoff)を入れて、設定が勝手に変わらないようにしておいた方が安全。
  • 尚、キー設定にある「ロックターゲット」の操作では、こんな事はない。

実用例(戦闘) Edit

戦闘中ターゲットを変えず自分に包帯を使う Edit

  • 末尾にバンデージと付くアイテムを、自分に対して使用する。
    /useitem [*バンデージ] <1>
    複数種類を所持している場合は、インベントリ番号の若いものが優先。

Mobに回復魔法などを誤爆しないための方法 Edit

  • 使用対象をプレイヤーに限定し、更に現在のターゲットにテクニックを使用。
    /cmd [ヒーリング] <player> %t
  • ただし、ペット ≠ <player> なので、ペットに対して使用できなくなるので注意。
    • リバイタル系は、ペットには無意味なので安心して使える。

1ボタンでサクリファイスディナー Edit

  • 普段は魔法チャージ武器を装備している人用。
    /swapequip 右手
    /cmd [サクリファイス ディナー]<near pet>召喚 ヴァンパイア バット(%1)
    /cmd [サモン ヴァンパイアバット]
    /cmd [先行入力防止]
    /swapequip 右手
    2行目 : 自分のバンパイアバットが近くに存在すれば、食べる。
    3行目 : 2行目が実行できなかった場合に限り、新たにコウモリを召喚する。

    チャージ武器を常時装備していない持ち替え不要な人は、/swapequip を削ればOK。
    ターゲットを指定しているため、育成ペットを誤食することがなくオススメ。

  • 召喚ペット使い向きのマクロ。
    /cmd [サクリファイス ディナー]<near pet>召喚 ヴァンパイア バット(%1)
    /cmd [サクリファイス ディナー]
    /cmd [サクリファイス ディナー]<pet1>
    /cmd [サモン ヴァンパイアバット]
    /cmd [先行入力防止]
    1行目 : 自分の召喚コウモリがいれば、召喚コウモリを食べる。
    2行目 : 1行目が実行できなかったら、ターゲットしているペットを食べる。(用済みになった召喚ペットを食べる)
    3行目 : 1〜2行目が実行できなかったら、一番最初に呼び出したペットを食べる。(残り滞在時間が一番短いものを食べる)
    4行目 : ここまでで何も食べれなかった場合、新たな食用コウモリを召喚。

    2〜3行目で召喚ペット以外も容赦なく食べるので、ウーなどの誤食に注意!!

盾マクロ2 Edit

  • 複数の盾技を、1ボタンで呼び出す。
    /equipitem [盾]
    /cmd [シールド ガード]
    /cmd [バッシュ]
    /cmd [スタン ガード]
    /cmd [カミカゼ]
    /cmd [先行入力防止]
    ディレイ中ではない技が出るので、「ガードしたつもりがディレイ中で発動しない」という事態を防げる。
    尚、先行入力を防止しておかないと、無意味に2連続で盾技を使うことになるので注意。

  • 「片手装備&盾」と「両手装備」切り替えマクロ
    「1スロット目は武器」「2スロット目は盾」が入る場所であることが前提で書いてある
    アイテムスロット番号は自分の使いやすい番号にしよう
    /swapequip 左手
    /equipitem 1
    /swapitembox 2
    /swapequip 左手

※マクロ解説

  • 片手装備&盾→両手装備の場合
    • 1行目で盾をドラッグ
    • 2行目で片手武器を1スロット目に入ってる両手武器と交換
    • 3行目に何も入ってない2スロット目に、ドラッグしている盾を入れる
    • 4行目は何もドラッグしてないので効果なし
  • 両手装備→片手装備&盾の場合
    • 1行目は盾を装備して無いので効果なし
    • 2行目で両手武器を1スロット目に入ってる片手武器と交換
    • 3行目で2スロット目に入ってる盾をドラッグ
    • 4行目でドラッグしてる盾を左手に装備

  • 上記マクロを踏まえた、「片手装備&盾」と「両手装備」の両方で盾が使えるマクロ
    /equipitem [盾]
    /cmd [盾技]
    /pause 10
    /equipitem 2 

※マクロ解説

  • 1行目で盾を装備(両手装備時は盾と両手装備が交換される。片手装備&盾の時は効果なし)
  • 2行目で盾技使用
  • 3行目は盾スキル発動中に装備が入れ替わらないようにディレイを掛けます。
  • 4行目は両手装備であった場合に2スロット目に両手装備が入っているので、それと盾を交換
    (片手装備&盾の時は効果なし)

  • 両手武器から盾持ち替え時にガードロストを防ぐマクロ。
    n=アイテムインベントリ
    1回目押せば上から順にディレイが貯まってる技が出る。
    2回目押せば武器を持ち直す。
    慣れれば盾モーション見てガードロストしないタイミングで2回目を押せるようになる 。
    欠点:アイテムインベントリの指定した番号に盾が入ってないと駄目(ディザーム系食らって違う番号に装備が落ちると面倒)
    /equipitem n tgl 
    /cmd [スタン ガード]
    /cmd [バッシュ]
    /cmd [シールド ガード] 
    /cmd [インパクト ステップ]
    /cmd [先行入力防止] 

  • 二刀流で盾を使うマクロです。
    マクロ発動中に変な操作するとごっちゃになってしまうので注意が必要。
    /equipitem 1              ← 適宜調整する
    /cmd [盾技] 
    /pause 25                 ← 適宜調整する
    /swapequip 左手 
    /swapitembox 1(適宜調整する&一行目のアイテムインベントリナンバーと合わせる)
    /swapequip 左手

弓を持ち替える Edit

  • 他の武器を持っていても、ボウが名前中に含まれるものを装備する。
    /swapequip 右手
    /swapequip 左手
    /swapitembox [*ボウ*]
    /swapequip 右手
    /swapequip 左手

  • 動作が若干異なるが、こちらも動作可能。
    /equipitem [*ボウ*] tgl

  • 弓と右手武器を持ち替えるマクロ。
    /swapequip 右手
    /swapitembox [弓]
    /swapequip 左手
    /swapitembox [右手武器]
    /swapequip 右手
    /swapitembox *
    ※マクロ解説
  • 右手武器 → 弓 の場合
    • 1行目、右手に装備している右手武器を掴む。
    • 2行目、掴んでいる右手武器と装備していない弓を交換
    • 3行目、弓を装備。
    • 4行目、装備していない右手武器を掴む。
    • 5行目、弓を既に装備しているため効果なし。(弓は両手武器)
    • 6行目、掴んでいる右手武器を、インベントリの一番若い空欄に置く。
  • 弓 → 右手武器 の場合(同じ種類の弓を複数持っているときちんと動作しない)
    • 1行目、右手に何も装備されていないので効果なし。
    • 2行目、同じもの(予備の弓)が無ければ効果なし。
    • 3行目、装備している弓を掴む。
    • 4行目、装備していない右手武器と、掴んでいる弓を交換。
    • 5行目、掴んでいる右手武器を装備。
    • 6行目、この時点で何も掴んでいないので効果なし。

複数種類の矢を打ち分ける Edit

  • 末尾にアローと付く矢を、矢/弾スロットに装填する。
    複数所持の場合はボックス番号の若いものが優先。
    この場合、2種類の矢の持ち替えとなる。
    /swapequip 矢/弾
    /swapitembox [*アロー]
    /swapequip 矢/弾

  • 矢3種類以上を交互に持ち替えるマクロ。
    例えば、ウッドアロー → アイアンアロー → ポイズンアロー → ウッドアロー というような場合。
  • 決めておいた場所(インベントリ番号)に、矢を置いておく必要がある。
    /swapitembox 1         ← 適宜調整する
    /swapequip 矢/弾
    /swapitembox 2         ← 適宜調整する
    /swapitembox 1         ← 1行目のインベントリ番号と合わせる
  • 上記の矢を入れるスロットを固定しなくてもよい方法。
    ただし、名前が「〜 アロー」限定。(光の矢や冥王の矢等は不可)
    /swapequip 矢/弾
    /equipitem [*アロー]
    /equipitem [*アロー]
    /swapitembox *
    1行目で、矢弾スロットに装備している「ウッド アロー」を手に掴む。 2行目で、インベントリ1番にある「アイアン アロー」を装備する。(1番が空白になる) 3行目で、1番が空白なので、インベントリ2番にある「ポイズン アロー」を装備する。(2番に「アイアン アロー」が置かれる) 4行目で、手に掴んでいた「ウッド アロー」を、インベントリ1番に置く。

指定した技だけ別の矢で撃つマクロ Edit

  • 例えば、ホークアイショットだけポイズンアローで撃つマクロは
    /equipitem [ポイズン アロー] 
    /cmd [ホークアイ ショット] 
    /cmd [先行入力防止]
    /equipitem [ウッド アロー]

確実にイリュージョン ソードを使ってソニック ストライク Edit

以下のマクロはインベントリが一杯でイリュージョンソードをドラッグしていたりする場合を想定していない。
このようなケースに対応するためには、イリュージョンソードを召喚するマクロ自体も工夫してみよう。
また、最後の行で刀剣以外の武器を装備するようにしていれば、とりあえずソニックストライクが発動することはない。

  • メイン武器を誤射しないマクロ。これでもうメイン武器を投げなくても済む。
    /equipitem [刀剣以外の右手装備]
    /equipitem [イリュージョン ソード]
    /cmd [ソニック ストライク]
    /cmd [先行入力防止]
    /equipitem [メイン武器]
    又は次のように。
    /swapequip 右手
    /equipitem [イリュージョン ソード]
    /cmd [ソニック ストライク]
    /cmd [先行入力防止]
    /swapequip 右手
    /swapitembox *

実用例(魔法) Edit

必要時だけスペルブック Edit

  • 1度目の選択で本にチャージして装備解除、2度目の選択で発動後に装備解除。
    普段は別の武器を装備している場合、/equipitem [本] tglをその装備に。
    /equipitem [本]
    /cmd [魔法]
    /cmd [先行入力防止]
    (空白行)
    /equipitem [本] tgl
  • 次のようにしても良い。
    /cmd [魔法]
    /equipitem [本]
    /cmd [先行入力防止]
    /equipitem [本] tgl

  • 上のマクロの応用。
    1度目で魔法1をチャージ。
    2度目で魔法1を発動し、魔法2を即詠唱開始。
    カオス フレアのノックバックを最大限に活かしたいときに。
    /cmd [魔法1]
    /equipitem [本]
    /cmd [先行入力防止]
    /equipitem [本] tgl
    /cmd [魔法2]
    /cmd [先行入力防止]

  • さらに応用。
    直接魔法が使用できる状況なら。即発動。
    そうでない場合はチャージ。
    /cmd [魔法]
    /cmd [魔法]
    /equipitem [本]
    /cmd [先行入力防止]
    /equipitem [本] tgl

確実にリザレクション Edit

  • 対象のキャラクターが同一エリア内にいるかチェックできるマクロ。
    魔法をかけたのに魂が抜けてて無駄になるということが無くなる。
    /equipitem [魔法チャージ武器]
    /w %t
    /cmd [リザレクション]
    詠唱中に、対象の(霊体の)居るエリアが表示されるので、別エリアなら詠唱をキャンセルすればよい。

ターゲットの有無関係なく、Buffをかけるマクロ Edit

  • ターゲット無しなら自分にBuff、ターゲット有りならそのキャラクターにBuff、を1マクロで行う。
    敵をターゲットしていても指定のキャラクターにBuffをかけることができる。
    欠点:他人のペットを対象にするには二行目は何も指定しない状態にしないといけないが、こうするとMobにもかけようとしてしまう。
    また、対人(アリーナやWarAgeなど)では1行目の%tを消さないと相手にBuffしてしまうので、自分用と味方用と分けて使おう。
  • 「必要時だけスペルブック」のマクロに応用すると便利…に思えるが、実際は
    詠唱 → チャージ → 開放・即時再詠唱…
    と、思っているように動作しないので注意。
    なお、「存在はするが、自分は覚えていないテクニック」を入れても、即時再詠唱をキャンセルすることは出来ない。

    /cmd [ヒーリング オール] <player>%t    ← 対人では %t を消す
    /cmd [ヒーリング オール] <pet>%t(%1)   ← ペット用。代入文字は直接指名に置き換えても可
    /cmd [ヒーリング オール] <1>

実用例(ペット) Edit

1ボタンでペットを呼び出すマクロ Edit

  • 多頭飼いでペット共闘をする時に。
    アニマルケイジを決まった場所(インベントリ番号)に置いておく必要があるが、いざという時にすぐ呼び出す事ができるので便利。
    /useitem 1    ← 適宜調整する
    /useitem 2    ← 適宜調整する
    /useitem 3    ← 適宜調整する
    /pause 5      ← ある程度のpauseを入れないと、ペットが反応しない事がある
    /petattack
    ペット呼出し後は、ペット全体への攻撃命令としても使えるので重宝する。
    /petcomeコマンドもペット全体に効果があるので、もう一つマクロを登録しておくと良い。

ペットの方を向いてからテクニックを使用 Edit

  • これで、自分の後方にいるペットにも技がかけらる。
    ペットが2頭以上の場合は、1行目を省いて自分でタゲる方がいいかも。
    /pettarget
    /locktarget on
    /pause 3
    /cmd [技・魔法]
    /locktarget off
    /target <lt>

ペットの死体を自分の足元に引き寄せるマクロ Edit

  • /petcorpse は、ペットの死体を自分の足元に引き寄せるコマンド。(範囲はかなり狭い)
    このマクロは、走りながらペットの死体を引っ張り続ける事ができるので、銀行やSBに戻る時に便利。
    /petcorpse
    /pause 30
    /petcorpse
    /pause 30
    /petcorpse

実用例(生産) Edit

大量生産用マクロ Edit

  • /swapitembox を用いると、該当アイテムを最大数量で掴む特性が 大量生産に便利。
    コンバイン窓から マウスカーソルを動かさずに 複数の材料を放り込めるので、時間と労力を節約できる。
  • 焼肉
    /cmd [料理(焼く)]
    /swapitembox [*肉]
    肉の種類を問わず焼肉が大量生産できる
  • バナナミルク
    /cmd [醸造]
    /swapitembox [ミルク]
    /pause 15
    /swapitembox [砂糖]
    /pause 8
    /swapitembox [バナナ]
    pause値は自分のリズムに合わせて調整すること。
    3行目 : /pause 15 は、醸造を使用してから コンバイン窓が出るまでの待ち時間を考慮。
    5行目 : /pause 8 は、砂糖を放り込む操作のための猶予時間。
  • 薬調合など
    /cmd [薬調合]
    /swapitembox [*]
    アイテムインベントリの一番若いアイテムを掴んでくれるので
    材料をインベントリの若い順にセットしておいてこのマクロを必要回数押せばよい
    料理、醸造で使用する場合は自動飲食に注意

残念ながら、スキル上げ等で行う 1個ずつ回数を多く行うコンバイン には流用できない
(そちらは空のレシピバインダーを使う方法がある)

実用例(その他) Edit

リコール レイション(ドリンク)の自動飲食 Edit

  • 召喚した飲み物・食べ物を、その場で飲食するマクロ。
    例えばリコールレイションの自動飲食マクロは、
    /cmd [リコール レイション]
    /pause 82
    /useitem [サモンス ミート]

マクロをもう10ページ追加するマクロ Edit

  • たったの10ページ程度じゃ足りないよ、全然足りないよ という方は...
    少々難しいので、理解出来る方のみ推奨
    現在のマクロを [main.ini] とし、追加する分を [sub.ini] とする。
    Title [サブマクロへ切り替える]
    /savemacro main.ini
    /pause 5
    /loadmacro sub.ini
    といったマクロを作り、一度実行する。このとき

    Save Macro -> '.\userdata\[キャラデータのフォルダ]\macro_main.ini' に保存しました
    Load Macro -> '.\userdata\[キャラデータのフォルダ]\macro_sub.ini' からの読み込みに失敗しました

    と出るが、気にせず先に作ったマクロを以下の通りに編集する。
    Title [メインマクロへ切り替える]
    /savemacro sub.ini
    /pause 5
    /loadmacro main.ini
    見た目をわかりやすくするため、アイコンも変えた方が良い。
    これで元々使っていた10ページのマクロが、10*2ページになる。
    その後はどちらかを編集し、以後このマクロで 「メインの10ページ」と「サブの10ページ」をワンタッチで切り替えることが出来る。

測定用マクロ Edit

ディレイの計測 Edit

  • 0.096秒単位で技のディレイを計測するには次のようなマクロを用意し、pause値を変えていく。
    出たpause値に0.096を掛けた数値が大体の秒数、6を掛けた数値が大体のディレイとなる。
    /cmd [測定する技]
    /pause 計測時間
    /cmd [測定する技]

  • 0.016秒単位(技の説明のディレイ等の単位)で技のディレイを計測するには次のようなマクロを用意し、空行の数を変えていく。
    空行1つでぎりぎり2回目が発動する場合は、pause値*6+3が正確なディレイ、空行3つならpause値*6+5が正確なディレイとなる。
    空行無しで発動してpause値を1減らし空行3つで発動しない場合はpause値*6+0〜2で不確定のためSTや装備補正で計測出来る範囲に調整する。
    /cmd [測定する技]
    /pause 計測時間
    (空行)
    /cmd [測定する技]

発生時間の計測 Edit

  • 0.096秒単位で技の発生時間や効果時間を計測するには次のようなマクロを用意し、pause値を変えていく。
    出たpause値に0.096を掛けた数値が大体の秒数、6を掛けた数値が大体の発生時間・効果時間となる。
    事前にメッセージ制御を使ってダメージやその他の効果をシステムに表示するようにしておこう。
    pauseを1でも増減してしまうとlocとダメージ・Buffのログが前後逆になってしまう状態が一番正確な値。
    /cmd [測定する技]
    /pause 発生時間      ← 発生時間を計測する場合はここを記録する。効果時間を計測する場合はここを計算に入れない。
    /loc                 ← ログを出し、発生時間の終了と効果時間の開始を明確にする。
    /pause 効果時間      ← 効果時間を計測する場合はここを記録する。
    /loc                 ← ログを出し、効果時間の終了を明確にする。

  • 0.016秒単位(技の説明のディレイ等の単位)で技の発動時間を計測するには次のようなマクロを用意し、空行の数を変えていく。
    1つ目のマクロの空行1(2)つでぎりぎり判定用の技が発動する場合は、pause値*6+3(4)が正確な発動時間となる。
    空行無しでぎりぎり発動する場合はpause値*6-1〜+2の範囲で確定出来ないため2行目に発動時間が既知の適当な技を挿入し試行する。
    /cmd [測定する技]
    /pause 計測時間
    (空行)
    /cmd [判定用のその場で使える技]
    /cmd [先行入力防止]

知っておくと便利なこと Edit

情報提供 Edit

編集メモ Edit

  • 基本>応用>実用例 の流れで再編
    • 実用例は、ジャンル毎に分けた方が見やすい
  • 細かい点は、まだ直してないので、重複する内容が多いかも

コメント Edit



*1 発動時間のみも含む

トップ   編集 凍結 差分 バックアップ 添付 複製 名前変更 リロード   新規 一覧 単語検索 最終更新   ヘルプ   最終更新のRSS
Last-modified: 2009-08-07 Fri 16:39:53 JST (3510d)